MpPassiveFishingBot v3.4 : PTS/LIVE Multi-account fishing bot

[mpmoi]

Hey guys !

PTS support is back ! I'll now look forward on the bootdrop system!

Requierments : AutoHotKey (last version I guess)

How it works :
1)Download Source code (wait for @Psychotic @Wyo @Buddie approval or paste it in a .ahk file)
2)Start it (Tutorial here : https://www.mpgh.net/forum/showthread.php?t=1150041 )
3)Press Ctrl + F while facing water/lava/chocolate.

-You can start it on as many accounts as you want.
-Press Ctrl + F again to stop fishing on focused window.
-To close the bot simply close the the GUI.

Updating pointers :
Pointers will be updated as often as I can.
You can still find them by yourself or check the forums : Nippy's Fishbot pointers should work.
To manually change the pointer, edit the config file in the same directory as the .ahk file. Then restart the script.
Here is a tutorial for finding pointers : https://www.mpgh.net/forum/showthread.php?t=1150085
Here is a tool that should find pointers itself : https://www.mpgh.net/forum/showthread.php?t=1195573

Not working ?
-After an update :
Check the last comments to see if there's any new pointer.
If not, post here and wait for someone to post it or me to update it
-Script not starting :
Describe your issue here in comment
-Other :
Press the 'info' button on the GUI, then press "Copy Debug Data" and paste it here. It should look like this :

 

Version = 3.0
Pointer = 0x00C8FF24
Water Offsets = 0x8+0xb4+0x28+0x22c
Lava Offsets = 0x8+0xb4+0x28+0x6e8
Chocolate Offsets = 0x8+0xb4+0x28+0x488
Water State Offsets = 0x1bc+0x4+0x748+0x1ec
Lava State Offsets = 0x1bc+0x4+0x690+0x88
Chocolate State Offsets = 0x1bc+0x4+0x748+0x448
Client:
PID = 4336
Handle = 0x200570
Base = 17104896
Water Address = 96185852
Lava Address = 96187064
Chocolate Address = 96186456
Water State Address = 96183132
Lava State Address = 96182528
Chocolate State Address = 96183736
Client:
PID = 8840
Handle = 0x560580
Base = 17104896
Water Address = 90353164
Lava Address = 90354376
Chocolate Address = 90353768
Water State Address = 90350444
Lava State Address = 90349840
Chocolate State Address = 90351048

Then wait for an answer

/!\ People seems to have hurdles on non-english versions
/!\ Your fishing hotkey must be 'F'

 

#SingleInstance force
#IfWinActive,Trove
#NoEnv
#Persistent
SetWorkingDir %A_ScriptDir%
SendMode Input
SetBatchLines -1

if NOT A_IsAdmin{
	Run *RunAs "%A_ScriptFullPath%"
	ExitApp
}

Process,Exist,TeamViewer.exe
  If (ErrorLevel)
    Msgbox,% "Teamviewer is currenly running. This is a known program to cause issues with the fishbot. Please close it or disable quick connect feature. If issues still happen try to uninstall it."

SplashTextOn,500,25,mpPassiveFishingBot,Initializing and updating pointer and offsets, please wait...

global Active:=Object()
global ver:=3.4
global dataVer:=1
global ptr:="0x0"
global wOfts:="0x0"
global lOfts:="0x0"
global cOfts:="0x0"
global wSOfts:="0x0"
global lSOfts:="0x0"
global cSOfts:="0x0"
global ptrPTS:="0x0"
global wOftsPTS:="0x0"
global lOftsPTS:="0x0"
global cOftsPTS:="0x0"
global wSOftsPTS:="0x0"
global lSOftsPTS:="0x0"
global cSOftsPTS:="0x0"
global iniFile:=A_ScriptDir "/config"ver ".ini"

if (FileExist(iniFile)){
	IniRead,dataVer,%iniFile%,Global,dataVer
	IniRead,ptr,%iniFile%,Global,ptr
	IniRead,wOfts,%iniFile%,Global,wOfts
	IniRead,lOfts,%iniFile%,Global,lOfts
	IniRead,cOfts,%iniFile%,Global,cOfts
	IniRead,wSOfts,%iniFile%,Global,wSOfts
	IniRead,lSOfts,%iniFile%,Global,lSOfts
	IniRead,cSOfts,%iniFile%,Global,cSOfts
	IniRead,ptrPTS,%iniFile%,Global,ptrPTS
	IniRead,wOftsPTS,%iniFile%,Global,wOftsPTS
	IniRead,lOftsPTS,%iniFile%,Global,lOftsPTS
	IniRead,cOftsPTS,%iniFile%,Global,cOftsPTS
	IniRead,wSOftsPTS,%iniFile%,Global,wSOftsPTS
	IniRead,lSOftsPTS,%iniFile%,Global,lSOftsPTS
	IniRead,cSOftsPTS,%iniFile%,Global,cSOftsPTS
}

WebRequest:=ComObjCreate("WinHttp.WinHttpRequest.5.1")
WebRequest.Open("GET","https://dl.dropb"+"oxuserconten*****m/u/52517919/MpFishPointer.txt")
WebRequest.Send()

global res:=StrSplit(WebRequest.ResponseText,"$")

if (res[1]>dataVer){
	global dataVer:=res[1]
	global ptr:=res[2]
	global wOfts:=res[3]
	global lOfts:=res[4]
	global cOfts:=res[5]
	global wSOfts:=res[6]
	global lSOfts:=res[7]
	global cSOfts:=res[8]
	global ptrPTS:=res[9]
	global wOftsPTS:=res[10]
	global lOftsPTS:=res[11]
	global cOftsPTS:=res[12]
	global wSOftsPTS:=res[13]
	global lSOftsPTS:=res[14]
	global cSOftsPTS:=res[15]
	IniWrite,%dataVer%,%iniFile%,Global,dataVer
	IniWrite,%ptr%,%iniFile%,Global,ptr
	IniWrite,%wOfts%,%iniFile%,Global,wOfts
	IniWrite,%lOfts%,%iniFile%,Global,lOfts
	IniWrite,%cOfts%,%iniFile%,Global,cOfts
	IniWrite,%wSOfts%,%iniFile%,Global,wSOfts
	IniWrite,%lSOfts%,%iniFile%,Global,lSOfts
	IniWrite,%cSOfts%,%iniFile%,Global,cSOfts
	IniWrite,%ptrPTS%,%iniFile%,Global,ptrPTS
	IniWrite,%wOftsPTS%,%iniFile%,Global,wOftsPTS
	IniWrite,%lOftsPTS%,%iniFile%,Global,lOftsPTS
	IniWrite,%cOftsPTS%,%iniFile%,Global,cOftsPTS
	IniWrite,%wSOftsPTS%,%iniFile%,Global,wSOftsPTS
	IniWrite,%lSOftsPTS%,%iniFile%,Global,lSOftsPTS
	IniWrite,%cSOftsPTS%,%iniFile%,Global,cSOftsPTS
	TrayTip ,mpPassiveFishingBot,Pointers and offsets updated
}

Gui,1:New
Gui 1:-Resize -MinimizeBox
Gui,1:Add,ListView,Checked -Hdr grid -ReadOnly -LV0x10 w250,| | | | |
Gui,1:Add,Button,gInfo w250,&Info

Gui,2:New
Gui 2:-Resize -MinimizeBox +ToolWindow
Gui,2:Add,Text,,% "Current version : "ver "`nPointer : "ptr "`nWater offsets : "wOfts "`nLava offsets : "lOfts "`nChocolate offsets : "cOfts "`nWater state offsets : "wSOfts "`nLava state offsets : "lSOfts "`nChocolate state offsets : "cSOfts "`nPTS Pointer : "ptrPTS "`nPTS Water offsets : "wOftsPTS "`nPTS Lava offsets : "lOftsPTS "`nPTS Chocolate offsets : "cOftsPTS "`nPTS Water state offsets : "wSOftsPTS "`nPTS Lava state offsets : "lSOftsPTS "`nPTS Chocolate state offsets : "cSOftsPTS
Gui,2:Add,Button,gDebug ,&Copy Debug Data

SplashTextOff

if (res[16]>ver){
	MsgBox,4,,% "Version "res[16] " available, go to MPGH topic ? (press Yes or No)"
	IfMsgBox Yes
		Run % "https://www.mpgh.net/forum/showthread.php?t="res[17]
}

GUI,1:Show,,mpPassiveFishingBot

SetTimer,Scan,250
SetTimer,Update,999

TrayTip,mpPassiveFishingBot,Bot started ! Press "Ctrl + f"on water/lava/chocolate !
return

^f::
	WinGet,pid,pid,A
	nActive:=Object()
	fnd:=false
	for i,Cur in Active{
		if (Cur[1]=pid)
			fnd:=true
		else
			nActive.Insert(Cur)
	}
	if (!fnd){
		nActive.Insert([pid,0,0,0,0,"Detecting","Detecting"])
		TrayTip,mpPassiveFishingBot,Bot started on %pid%!
	}else
		TrayTip,mpPassiveFishingBot,Bot stopped on %pid%!
	global Active:=nActive
	return

Scan:
	for i,C in Active
		if (C[4]=0){
			pid:=C[1]
			WinGet,h,ID,ahk_pid %pid%
			Base:=getProcessBaseAddress(h)
			wSAdr:=GetAddress(pid,Base,ptr,wSOfts)
			lSAdr:=GetAddress(pid,Base,ptr,lSOfts)
			cSAdr:=GetAddress(pid,Base,ptr,cSOfts)
			wSAdrPTS:=GetAddress(pid,Base,ptrPTS,wSOftsPTS)
			lSAdrPTS:=GetAddress(pid,Base,ptrPTS,lSOftsPTS)
			cSAdrPTS:=GetAddress(pid,Base,ptrPTS,cSOftsPTS)
			if (ReadMemory(wSAdr,pid)=1){
				C[4]:=GetAddress(pid,Base,ptr,wOfts)
				C[5]:=wSAdr
				C[6]:="Water"
				C[7]:="Live"
			}else if (ReadMemory(lSAdr,pid)=1){
				C[4]:=GetAddress(pid,Base,ptr,lOfts)
				C[5]:=lSAdr
				C[6]:="Lava"
				C[7]:="Live"
			}else if (ReadMemory(cSAdr,pid)=1){
				C[4]:=GetAddress(pid,Base,ptr,cOfts)
				C[5]:=cSAdr
				C[6]:="Chocolate"
				C[7]:="Live"
			}else if (ReadMemory(wSAdrPTS,pid)=1){
				C[4]:=GetAddress(pid,Base,ptrPTS,wOftsPTS)
				C[5]:=wSAdrPTS
				C[6]:="Water"
				C[7]:="PTS"
			}else if (ReadMemory(lSAdrPTS,pid)=1){
				C[4]:=GetAddress(pid,Base,ptrPTS,lOftsPTS)
				C[5]:=lSAdrPTS
				C[6]:="Lava"
				C[7]:="PTS"
			}else if (ReadMemory(cSAdrPTS,pid)=1){
				C[4]:=GetAddress(pid,Base,ptrPTS,cOftsPTS)
				C[5]:=cSAdrPTS
				C[6]:="Chocolate"
				C[7]:="PTS"
			}else if (C[3]>5){
				SendF(pid)
				C[3]:=0
			}
		}else
			if (C[3]>10&&ReadMemory(C[4],C[1])=1){
				C[2] ++
				C[3]:=0
				SendF(C[1])
			}else if (C[3]>5&&ReadMemory(C[5],C[1])=0){
				SendF(C[1])
				C[3]:=0
			}
	return

Info:
	Gui,2:Show,,Info
	return

Debug:
	msg:="[SP" "OILER=Debug][CO" "DE]Version = "ver "`nPointer = "ptr "`nWater Offsets = "wOfts "`nLava Offsets = "lOfts "`nChocolate Offsets = "cOfts "`nWater State Offsets = "wSOfts "`nLava State Offsets = "lSOfts "`nChocolate State Offsets = "cSOfts "`nPTS Pointer = "ptrPTS "`nPTS Water Offsets = "wOftsPTS "`nPTS Lava Offsets = "lOftsPTS "`nPTS Chocolate Offsets = "cOftsPTS "`nPTS Water State Offsets = "wSOftsPTS "`nPTS Lava State Offsets = "lSOftsPTS "`nPTS Chocolate State Offsets = "cSOftsPTS
	WinGet,l,list,ahk_exe Trove.exe
	loop %l%{
		WinGet,pid,pid,% "ahk_id "l%a_index%
		Base:=getProcessBaseAddress(l%a_index%)
		msg:=msg "`nClient"a_index ":`nPID = "pid "`nHandle = "l%a_index% "`nBase = "Base "`nWater Address = "GetAddress(pid,Base,ptr,wOfts) "`nLava Address = "GetAddress(pid,Base,ptr,lOfts) "`nChocolate Address = "GetAddress(pid,Base,ptr,cOfts) "`nWater State Address = "GetAddress(pid,Base,ptr,wSOfts) "`nLava State Address = "GetAddress(pid,Base,ptr,lSOfts) "`nChocolate State Address = "GetAddress(pid,Base,ptr,cSOfts) "`nPTS Water Address = "GetAddress(pid,Base,ptrPTS,wOftsPTS) "`nPTS Lava Address = "GetAddress(pid,Base,ptrPTS,lOftsPTS) "`nPTS Chocolate Address = "GetAddress(pid,Base,ptrPTS,cOftsPTS) "`nPTS Water State Address = "GetAddress(pid,Base,ptrPTS,wSOftsPTS) "`nPTS Lava State Address = "GetAddress(pid,Base,ptrPTS,lSOftsPTS) "`nPTS Chocolate State Address = "GetAddress(pid,Base,ptrPTS,cSOftsPTS)
	}
	msg:=msg "[/CO" "DE][/SPO" "ILER]"
	clipboard=%msg%
	MsgBox,Debug data copied to clipboard
	return

GuiClose:
	ExitApp

Update:
	for i,C in Active
		C[3]++
	LV_DELETE()
	LV_Add("","PID","Server","Liquid","Reeled","Timer")
	WinGet,l,list,ahk_exe Trove.exe
	WinGet,cur,pid,A
	WinGet,name,ProcessName,ahk_pid %cur%
	if(name !="Trove.exe")
		ToolTip
	loop %l%{
		WinGet,pid,PID, % "ahk_id " l%a_index%
		found:=false
		for i,C in Active
			if (C[1]=pid){
				found:=true
				LV_Add("Check",C[1],C[7],C[6],C[2],C[3])
				if (cur=pid)
					ToolTip,% "Fishing`nPID : "C[1] "`nServer : "C[7] "`nLiquid : "C[6] "`nReeled : "C[2] "`nTimer : "C[3],0,0
			}
		if (!found){
			LV_Add("",PID,"Not fishing","Not fishing",0,0)
			if (cur=pid)
				ToolTip,% "Not fishing`nPid : "pid,0,0
		}
	}
	LV_ModifyCol()
	return

SendF(PID){
	ControlSend,ahk_parent,{f down},ahk_pid %pid%
	Sleep,90
	ControlSend,ahk_parent,{f up},ahk_pid %pid%
}

getProcessBaseAddress(hnd){
	return DllCall( A_PtrSize=4 ? "GetWindowLong": "GetWindowLongPtr","Ptr",hnd,"Int",-6,"Int64")
}

GetAddress(PID,Base,Adr,Ofts){
	p:=ReadMemory(base + Adr,PID)	
	OftsSpl:=StrSplit(Ofts,"+")
	loop,% (OftsSpl.MaxIndex() - 1)
			p:=ReadMemory(p + OftsSpl[a_index],PID)
	if (Ofts != "")
		p:=p + OftsSpl[OftsSpl.MaxIndex()]
	return p
}

ReadMemory(MADDRESS,pid){
	VarSetCapacity(MVALUE,4,0)
	ProcessHandle:=DllCall("OpenProcess","Int",24,"Char",0,"UInt",pid,"UInt")
	DllCall("ReadProcessMemory","UInt",ProcessHandle,"Ptr",MADDRESS,"Ptr",&MVALUE,"Uint",4)
	loop 4
		result +=*(&MVALUE + A_Index-1) << 8*(A_Index-1)
	return result
}

 

 

V1.0 (2670b):
Initial release

v1.1 (2781b):
Timer correction
Hard optimisation

v1.2 (3659b):
Now automatically updating pointers !
Few issues corrected

v1.3 (3649b):
Splash text
Tray messages added (no longer messages box)
Few optimisations

v1.4 (3830b):
Edited timer setup
Less hurdles with bot stuck (reeling while fishing)

v1.5 (4231b):
Check for updates and open related thread
MOTD added (for changelogs)
Edited timer setup
Less hurdles with bot stuck (reeling while fishing)

v1.6 (4697b):
GUI Added
Removed useless stuff
Now counting found accounts and reeled fish

v1.7 (6237b):
Debug added

v1.8 (6267b):
Corrected a cross-GUI fix

v1.9 (6266b):
Fixed a closing bug

v2.0 (8116b):
Fixed a glitch on the base address on debug window
Added a PTS support

v2.1 (7990b):
Modified window selection to prevent selection non-trove window
Removed handle reading (already have it)
Cleaned up initial values of pointer/offsets(were wrong)

v2.2 (7529b):
Minor optimisations and crash fixes

v3.0 (8431b):
Core code remade
Fixed crash with multiple accounts
GUI looks better
Added a button to copy account and vars list, BBCODE formatted

v3.1 (7512b):
Gui and performance optimisations

v3.2 (8177b):
Fixed the lure glitch
Stopping the bot if it get stuck

v3.3 (6863b):
Removed the code that checked if the bot get stuck
Added a tooltip when on a trove window saying if this account is fishing or not, and how many fish have been reeled
Fixed an issue with the config.ini file


v3.4 (9125b):
Few bugfixes
Added back PTS support

Special thanks :
@reppin Who let me make a bot and use part of it's memory-reading code ! Check out his awesome fishing bot !

Disclaimer :
I will not be responsible of any ban you get by using this !

There are the virus scans :
https://virusscan.jotti.org/en-US/fi...job/71d8ottapm
https://www.virustotal.com/en/file/6...is/1480357061/

NOTE : Old thread can be closed

[[MPGH]Wyo]

I'ts safe. Good hacking

[ninymug]

IS there any way that i can modify the code to not wait so long before casting again?
Thanks for the bot! :3

[mpmoi]

IS there any way that i can modify the code to not wait so long before casting again?
Thanks for the bot! :3

Sure!
This will be configurable on next version.

Replace "5" here :

C[3]>5

with the amount of time you want it to wait between recasts (I'd suggest not going lower than 2-3s)
Take care to replace both 2 occurences

- - - Updated - - -

Working on bootdrop right now

[hugosilvag6]

Sorry for asking, but what is PTS?
Adorable hack, congrats!

[mpmoi]

Sorry for asking, but what is PTS?
Adorable hack, congrats!

Test server for trove

[Bromantic]

tried to add you on skype just now but not sure if its working
was gonna ask some questions and make some suggestions

[mpmoi]

tried to add you on skype just now but not sure if its working
was gonna ask some questions and make some suggestions

Sure np !
Bootdrop is on the way ! Testing rn, i'll be releasing in a few days

[kevvv1]

Sure np !
Bootdrop is on the way ! Testing rn, i'll be releasing in a few days

I'm guessing your boot drop has to foreground the window?

[mpmoi]

I'm guessing your boot drop has to foreground the window?

Yep, no way to do it without bringing it to foreground for now
(gotta take a look at packet editing for this)

[kevvv1]

Yep, no way to do it without bringing it to foreground for now
(gotta take a look at packet editing for this)

Another alternative would be to inject a dll and run the function itself.

[mpmoi]

Another alternative would be to inject a dll and run the function itself.

Yeah I know but i'm not yet into dll injection