Using variables as functions.

[[MPGH]master131]

Well have you ever seen code like this and thought wtf?

[[level.callbackStartGameType]]();

That is was I call a variable function. It runs a function that is assigned to a variable. If you search through the game's files you will find this:

level.callbackStartGameType = maps\mp\gametypes\_globallogic::Callback_StartGameType;

What that means is the code in the first box runs the function that is assigned in the second box. Now that we have found out this. We can use variables as functions.

Say, inside my _rank.gsc file I had these two sub-procedures (, VB):

onPlayerSpawned()
{
    self endon("disconnect");
    for(;;)
    {
        self waittill("spawned_player");
    }
}

doSuicide()
{
    self suicide();
}

How do I run doSuicide() as a function?
Well first you need to declare your function. Lets name it byeCruelWorld. To link it to a function that's in the same file and then run it, you do this:

byeCruelWorld = ::doSuicide;
self [[byeCruelWorld]]();

Now my onPlayerSpawned looks like this:

onPlayerSpawned()
{
    self endon("disconnect");
    for(;;)
    {
        self waittill("spawned_player");
        byeCruelWorld = ::doSuicide;
        self [[byeCruelWorld]]();
    }
}

So now when I spawn, it runs the function that is assigned to 'byeCruelWorld' which causes me to commit suicide. However there is a downside since I can only use 'byeCruelWorld' in the same function for obvious reasons.

What if I want to use this function in anywhere BUT the function is in the same file I'm delcaring it in?
You would do this and delcare it as a global variable.

self.byeCruelWorld = ::doSuicide;
// In any file:
self [[self.byeCruelWorld]]();

What if I want to use this function in anywhere AND the function is in another file?
You would link it in a simillar manner of running a function or thread from another file.

self.byeCruelWorld = maps\mp\gametypes\_rank::doSuicide;
// In any file:
self [[self.byeCruelWorld]]();

What if I want to pass arguments through?
You pass your arguments through the pair of brackets before the semi-colon.

level.endGameNow = maps\mp\gametypes\_globallogic::endGame;
level [[level.endGameNow]]("allies", "Allies rule!");

What if I want to thread the variable function?
Simple, just add 'thread' before the variable.

self thread [[self.byeCruelWorld]]();

[Insane]

Very useful. Gj Master

[♪~ ᕕ(ᐛ)ᕗ]

useful and sexy =P Gewd job dude!
/Thanked

[sammysfat]

that is cool ur teaching me alot