Vindictus Enalber

[Kiette]

Hi everyone. I may be new here, but I for one ain't one to show for it. What I have here is something I've been working on for the past week or so. It started off as a very simple batch file script that enabled and disabled cheats and such without needing to do anything to it. However I'm never satisfied, so I just kept adding to it, improving it, and adding to it some more. What you see here is the finalized version of this work.

This is by no means a mod/bot/cheat. This is a tool for you guys to use to enable your mod/bots/cheats and various other things.

Information
This script is a very complex batch file that will automatically enable/disable any mods you choose. Whether they are cheats, bots, or mods; this will automatically take care of everything you need. Run it once to backup the necessary files and enable some cheats. Run it again to automatically disable all cheats by restoring the original files and configurations. It will dynamically be able to handle an unlimited number of cheats, mods, or bots!

Summary of features:

• Dynamically add any mod, bot, cheat you want.
• Automatically disable all cheats or bots.
• Automatic backup/restore features.
• Automatically run the game and terminate with ban prevention measures
• Automatically create a combined readme file of anything you would need.
• Version change tracking. If the clients version ever changes, it will immediately let you know.

Installation

WARNING - Have any cheats/modded files installed? Restore them to their originals first! Use the instructions below to place these files where they should be.

1) Place the contents of this rar file into your Vindictus folder

Default is going to be in C:\Nexon\Vindictus\en-US\.
EnablerCheats folder should be like this C:\Nexon\Vindictus\en-US\EnableCheats
[Vindictus Enabler].bat will be in C:\Nexon\Vindictus\en-US\

If you are doing cheats:
2A) Go into the EnablerFiles folder and put your Cheat hfs files into their own folder.

For example for PieBinds:

A) Goto EnablerFiles\Cheats\
B) Create a folder called PieBind
C) Place all hfs files here.

If you are doing bots:
2B) Go into the EnablerFiles folder and put your Bot hfs files into their own folder under hfs.

For example for BloodLord:

A) Goto EnablerFiles\Bots\
B) Create a folder called BloodLord
C) Create a folder called hfs within BloodLord
D) Place all hfs files here.
E) Place any scripts/programs that makes the bot run in BloodLord

If you are doing mods:
2C) Go into the EnablerFiles folder and put your Mod hfs files into their own folder.

For example for FemaleLann:

A) Goto EnablerFiles\Mods\
B) Create a folder called FemaleLann
C) Place all hfs files here.

3) Optional: Place ReadMe.txt file in whichever cheat/bot you want one for

For example I keep what my binds are for PieBinds:

A) Goto EnablerFiles\Cheats\PieBinds
B) Create a new text file and name it ReadMe.txt (case-sensitivity matters)
C) Copy & Paste your information within the text file.

4) Conditional: If you do not have Vind installed in the usual C:/Nexon/Vindictus...

You must edit the bat file to where you have Vind:

A) Open up [Vindictus Enabler].bat in notepad or notepad++
B) At the top you'll see a section of variables
C) Edit the Directory variable, following the same symantics as whats there.

5) Optional: Customize the script to run the game, show a combined readme file, or show the bot folder

You must edit the bat file for this:

A) Open up [Vindictus Enabler].bat in notepad or notepad++
B) At the top you'll see a section of variables
C) Edit the variables here to what you want.

Options
There are 3 options

bRunGame - This will ask whether you want to run the game. Doing this will launch the game, press any key while it runs to terminate the program and delete any logs. This is mainly a placebo for ban prevention. If cheats are enabled, it will ask to run the game with cheats instead of disabling the mods first. Saying no will disable mods. On my system the taskkill command does not work, so its off by default.

bOpenBotFolder - This will ask if you want to open the bot's folder when you enable it. This is useful for when you want to immediately start the script file the make it work. This is enabled by default.

bReadMe - This will ask if you want to look at the combined readme of enabled cheats. This is great for people who constantly forget what the keybinds are and so on. This only really works if you have added the appropriate ReadMe text files on enabled cheats/bots. Otherwise it'll just give you a report of if not finding any. This is enabled by default.

Cheats
Cheats files like PieBundle, PermBind, and so on all go within the Cheats folder under their own specific folder.

If you want the script to display the what these files do (like what keybinds they use), make a ReadMe.txt file with whatever information you want. If you have turned off the prompt for readme files, you can find the combined readme file in EnabledFiles\EnabledReadme.txt

Bots
Bot files like AutoFarming all go within the Bots folder under their own specific folder. The hfs files must go within a hfs folder within this folder. You can place any AutoIt scripts or programs in the base folder for easy keeping.

Enable the bOpenBotFolder option to allow the batch file to automatically open the bot's folder once it is enabled. This way you can easily run the bot programs you need.

Side note: Enabling a bot automatically skips the chance to enable cheat files. If you require a specific cheat file, place it within the hfs folder of the particular bot.

Mods
Mod files like FemaleLann all go within the Mods folder under their own specific folder.

Unlike cheats or bots, mods are always enabled and never disabled. Backup files for mods are kept in the Mods folder for safe keeping.

Backups
The batch file will automatically detect potential modified files from both the Bots and Cheats folders and create a backup before beginning. Everything will be kept within the Backups folder, including your config.cfg file for any cheats/bots that change keybinds.

These files will never be touched by the batch file. They are only used to restore and disable all bots/cheats.

Mods keep their backups within the Mods folder. You must manually restore these when needed.

Last tidbits

Still don't understand? Ok. I got you covered. I've uploaded an example of how to get everything working. The example includes the PieBundle by ILikePie550, PermBinds by nunya, Blood Lord script by omagad00, and Auto Farming by mikehan. This was done in Ep7 before the Karok update. This is only an example. Don't use these until they are deemed safe following the big update! This is my personal setup for the script. It has nothing initialized, it is setup in a way so that it'll start up, make backups, and be ready for use immediately.

The default version (the smaller one) is this script with all the folders needed, but with no mods. You must add them appropriately before use. It prevent you from doing anything until it is set up properly.

Updated - 6-14 12:40 PST
Virus Total Scan - For default version
Virus Total Scan - For example version
VirScan.org Scan - Default version
VirScan.org Scan - Example Version - Wow 20 file limit that even includes folders? Just barely made it under that.

And just for those who want to know. Here is the source~

@EcHo off
setlocal
title Vindictus Enabler

::=====================================
::			Internal Variables
::=====================================

:: IMPORTANT! Edit this to where the game is!
::		%HOMEDRIVE% = Where windows is installed (eg. C:\)
set Directory=%HOMEDRIVE%\Nexon\Vindictus\en-US\

:: Prompts you to run the game or not. Mainly for placibo ban prevention.
::	(0: Disabled | 1: Enabled)
:: 		Note: This feature only half works on my end.
set bRunGame=0

:: Prompts if you want to open the bot folder for running scripts/utils.
::	(0: Disabled | 1: Enabled)
set bOpenBotFolder=1

:: Prompts whether to launch ReadMe files for enabled Bots/Cheats
::	Works best with Notepad++ when opening multiple files.
::	(0: Disabled | 1: Enabled)
set bReadMe=1

:: Do not edit - Keeps track of the number of cheats enabled.
set ChtNumber=0

:: Do not edit - Keeps track of the number of bots available.
set BotNumber=0

:: Do not edit - Keeps track of the number of mods available.
set ModNumber=0

::=====================================
::			Initialization
::=====================================

:initialize
echo Initializing...

:: For non-Vista/Win7 and Admin mode.
cd %Directory%

:: Create backup folder first
if not exist EnablerFiles\Backups md EnablerFiles\Backups

:: Backup your current config files
if not exist EnablerFiles\Backups\config.cfg copy cfg\config.cfg EnablerFiles\Backups\config.cfg

:: Backup the current version of the client
if not exist EnablerFiles\CurrentInfo.txt copy CurrentInfo.txt EnablerFiles\CurrentInfo.txt

:: Create temporary ReadMe file.
if not exist EnablerFiles\EnabledReadMe.txt echo This file is for combining ReadMe files. >EnablerFiles\EnabledReadMe.txt

:: Recursively search for cheats, create default status file
echo Checking for Cheats...
for /R EnablerFiles\Cheats %%g in (.) do (
	if not "%%~ng" == "Cheats" (
		set /a ChtNumber=%ChtNumber% + 1
		if not exist EnablerFiles\Cheats\%%~ng\Status.txt echo disabled >EnablerFiles\Cheats\%%~ng\Status.txt
	)
)

:: Recursively search for cheat files, create backups
for /R EnablerFiles\Cheats %%z in (*.hfs) do (
	if not exist EnablerFiles\Backups\%%~nz.hfs copy hfs\%%~nz.hfs EnablerFiles\Backups\%%~nz.hfs
)

if "%ChtNumber%" == "0" echo -- No Cheats Found --

:: Recursively search for bots, create default status file, increment count
echo Checking for Bots...
for /R EnablerFiles\Bots %%g in (.) do (
	if not "%%~ng" == "Bots" (
		if not "%%~ng" == "hfs" (
			set /a BotNumber=%BotNumber% + 1
			if not exist EnablerFiles\Bots\%%~ng\Status.txt echo disabled >EnablerFiles\Bots\%%~ng\Status.txt
		)
	)
)

:: Recursively search for bot files, create backups
for /R EnablerFiles\Bots %%z in (*.hfs) do (
	if not "%%~nz" == "hfs" (
		if not exist EnablerFiles\Backups\%%~nz.hfs copy hfs\%%~nz.hfs EnablerFiles\Backups\%%~nz.hfs
	)
)

if "%BotNumber%" == "0" echo -- No Bots Found --

:: Now for mods - These will never be removed.
echo Checking for Mods...
for /R EnablerFiles\Mods %%g in (.) do (
	if not "%%~ng" == "Mods" (
		set /a ModNumber=%ModNumber% + 1
		if not "%%~ng" == "Backups" (
			call :ModBackups %%g %%~ng
		)
	)
)

if "%BotNumber%" == "0" echo -- No Mods Found --

:: Version matching
echo Checking for version change...
set /p version= <CurrentInfo.txt
set /p chtvers= <EnablerFiles\CurrentInfo.txt
if not "%version%" == "%chtvers%" (
	set errmsg= Version mismatch! Did the client update?
	goto Error
)

:: Set default overall status
if not exist EnablerFiles\CheatStatus.txt echo disabled >EnablerFiles\CheatStatus.txt

:: If it didn't detect any cheats, it'll error out.
if "%ChtNumber%" == "0" (
	if "%BotNumber%" == "0" (
		set errmsg= Could not find anything! Please make sure everything is in its own folder for cheats or under an hfs folder for bots!
		goto Error
))

set ChtNumber=0

echo Initializing complete!
echo.
GOTO begin

::=====================================
::			Start Script
::=====================================

:begin
echo =============== Vindictus Enabler ===============
echo.
set /p status= <EnablerFiles\CheatStatus.txt
echo STATUS OF CHEATS - %status%
echo.

:: If bRunGame isn't set, immediately just disable everything. No prompts needed.
if "%status%" == "enabled " ( 
	if "%bRunGame%" == "1" (
		call :RunGame gotodisable
		goto :EOF
	)
	goto DisableAll
)

if "%status%" == "disabled " goto StartChoices

set errmsg= Error reading current status!
goto Error

:StartChoices
:: Bot mode will not enable other cheats.
if not "%BotNumber%" == "0" set /p botmodo=Bot mode? {y/n} 
if "%botmodo%" == "y" (
	for /R EnablerFiles\Bots %%g in (.) do (
		if not "%%~ng" == "hfs" (
			if not "%%~ng" == "Bots" call :PromptCheat %%g %%~ng
		)
	)
)
:: If no bots were chosen, move on. Else enable em.
if not "%ChtNumber%" == "0" goto EnableCheats

echo.

:: Go through all folders and use PromptCheat function to do dirty work.
for /R EnablerFiles\Cheats %%g in (.) do (
	if not "%%~ng" == "Cheats" call :PromptCheat %%g %%~ng
)

if "%ChtNumber%" == "0" (
	set errmsg= No cheats selected.
	goto Error
)

goto EnableCheats

:PromptCheat
:: Helper function for enabling a given input
set /p userinput=Enable %2 {y/n} 
if "%userinput%" == "y" (
	echo enabled >%1\Status.txt
	set /a ChtNumber=%ChtNumber% + 1
)
if not "%userinput%" == "y" (
	echo disabled >%1\Status.txt
)

:: Clear userinput
set userinput=n
goto :EOF

::=====================================
::			Enable / Disable
::=====================================

:DisableAll
echo.
echo Disabling All Cheats...

:: Blind disable everything
for /R EnablerFiles\Cheats %%g in (*.txt) do (
	if "%%~ng" == "Status" (
		echo disabled >%%g
	)
)
for /R EnablerFiles\Bots %%g in (*.txt) do (
	if "%%~ng" == "Status" (
		echo disabled >%%g
	)
)

:: Safe restore of all backups.
for /R EnablerFiles\Backups %%z in (*.hfs) do (
	del hfs\%%~nz.hfs
	copy %%z hfs\%%~nz.hfs
)

:: Restore config files - All changes while stuff was enabled is now gone.
del cfg\config.cfg
copy EnablerFiles\Backups\config.cfg cfg\config.cfg

:: Remove any logs.
if exist HShield\hshield.log del HShield\hshield.log
if exist HShield\supdate.log del HShield\supdate.log
if exist HShield\HSUpChk.log del HShield\HSUpChk.log
if exist HShield\Update\supdate.log del HShield\Update\supdate.log
if exist "%UserProfile%\Documents\Vindictus\Report Error" rmdir /s /q "%UserProfile%\Documents\Vindictus\Report Error"

:: Reset ReadMe file.
echo This file is for combining ReadMe files. >EnablerFiles\EnabledReadMe.txt

echo.
echo disabled >EnablerFiles\CheatStatus.txt
echo Cheats are now DISABLED!
echo.
if "%bRunGame%" == "1" call :RunGame
pause
goto :EOF

:EnableCheats
echo.
echo Enabling Cheats...

:: Begin combined readme file.
echo ------------ Vindictus Enabler Combined Readme ------------ >EnablerFiles\EnabledReadMe.txt

:: Find all folders with mod files and use helper function to do dirty work
for /R EnablerFiles\Bots %%g in (.) do (
	if not "%%~ng" == "Bots" (
		if not "%%~ng" == "hfs" call :EnableSingleBot %%g %%~ng
	)
)
for /R EnablerFiles\Cheats %%g in (.) do (
	if not "%%~ng" == "Cheats" call :EnableSingleCht %%g %%~ng
)

:: For scripts that change keybinds.
echo Saving config.cfg...
del EnablerFiles\Backups\config.cfg
copy cfg\config.cfg EnablerFiles\Backups\config.cfg
echo.

echo enabled >EnablerFiles\CheatStatus.txt
echo Cheats are now ENABLED!
echo.
if "%bRunGame%" == "1" call :RunGame
if "%bReadMe%" == "1" (
	if not "%bRunGame%" == "1" (
		call :ReadMe
		goto :EOF
	)
)
pause
goto :EOF

:EnableSingleCht
::Checks if it is enabled, then looks for any hfs file and copies it
set /p chtstatus= <%1\Status.txt
if "%chtstatus%" == "enabled " (
	echo Enabling Cheat - %2
	
	:: Add combined readme header.
	echo. >>EnablerFiles\EnabledReadMe.txt
	echo ------------ %2 ReadMe ------------ >>EnablerFiles\EnabledReadMe.txt
	echo. >>EnablerFiles\EnabledReadMe.txt
	
	for /R %1 %%z in (*.hfs) do (
		del hfs\%%~nz.hfs
		copy %%z hfs\%%~nz.hfs
	)
	
	:: If a readme exists, combine it. >nul gets rid of reporting.
	if exist %1\ReadMe.txt copy /b EnablerFiles\EnabledReadMe.txt+"%1\ReadMe.txt" EnablerFiles\EnabledReadMe.txt  >nul
	if not exist %1\ReadMe.txt echo [No ReadMe found.] >>EnablerFiles\EnabledReadMe.txt
)
goto :EOF

:EnableSingleBot
::Checks if it is enabled, then looks for any hfs file and copies it
set /p chtstatus= <%1\Status.txt
if "%chtstatus%" == "enabled " (
	echo Enabling Bot - %2
	
	:: Add combined readme header.
	echo. >>EnablerFiles\EnabledReadMe.txt
	echo ------------ %2 ReadMe ------------ >>EnablerFiles\EnabledReadMe.txt
	echo. >>EnablerFiles\EnabledReadMe.txt
	
	for /R %1/hfs %%z in (*.hfs) do (
		if not "%%~nz" == "hfs" (
			del hfs\%%~nz.hfs
			copy %%z hfs\%%~nz.hfs
		)
	)
	if exist %1\ReadMe.txt copy /b %1\ReadMe.txt+EnablerFiles\EnabledReadMe.txt EnablerFiles\EnabledReadMe.txt >nul
	if not exist %1\ReadMe.txt echo [No ReadMe found.] >>EnablerFiles\EnabledReadMe.txt
	if "%bOpenBotFolder%" == "1" call :OpenBot %1 %2
)
goto :EOF

:ModBackups
:: Creates a backup and enables the mod. This is semi-perminent.
for /R %1 %%z in (*.hfs) do (
	if not exist EnablerFiles\Mods\Backups\%%~nz.hfs (
	echo Installing Mod - %2
		copy hfs\%%~nz.hfs EnablerFiles\Mods\Backups\%%~nz.hfs
		del hfs\%%~nz.hfs
		copy %%z hfs\%%~nz.hfs
	)
)
goto :EOF

::=====================================
::			Util Functions
::=====================================

:RunGame
:: Only runs if set at top. Runs vind, allows you to close it after, delete any logs.
:: Currently taskkill does not work due to hackshield.
set /p rungame=Run the game? {y/n} 
if "%rungame%" == "y" (
	start Vindictus.exe
	if "%bReadMe%" == "1" call :ReadMe
	echo Starting Vind. Pressing a key after this will terminate the game.
	pause
	taskkill /f /im Vindictus.exe
	pause
	if exist HShield\hshield.log del HShield\hshield.log
	if exist HShield\supdate.log del HShield\supdate.log
	if exist HShield\HSUpChk.log del HShield\HSUpChk.log
	if exist HShield\Update\supdate.log del HShield\Update\supdate.log
	if exist "%UserProfile%\Documents\Vindictus\Report Error" rmdir /s /q "%UserProfile%\Documents\Vindictus\Report Error"
	goto :EOF
)

if "%1" == "gotodisable" goto DisableAll
goto :EOF

:OpenBot
:: Only runs if set at top.
set /p openfolder=Do you want to open the %2's folder? {y/n} 
if "%openfolder%" == "y" (
	cd %1
	start .
	cd %Directory%
)
goto :EOF

:ReadMe
:: Only runs if set at top. Displays the combined ReadMe files.
set /p doreadme=Do you wish to see any ReadMe files? {y/n} 

if "%doreadme%" == "y" (
	start EnablerFiles\EnabledReadMe.txt 
)
goto :EOF
	
:Error
:: Error - Requires you set errmsg.
color 04
echo.
echo ERROR! Exiting now!
echo Message:%errmsg%
echo.
pause
goto :EOF

[Pie]

This would be a handy tool D:
Now ppl gonna be even lazier >.<

@Sid @Hell_Demon

[Karleo]

Looks good

I remember when there wasn't .hfs hacking or any console released.

Those times are long gone now :3

[Iopp]

Ooooo

So I will not need to open up my Vindictus files and do all that file dragging and stuff?

[Som3RussianChick]

nice release, this real be real handy for me :]

[sdsd4564]

Download file is deactivated, what did i do

[Jabuuty671]

Approved .nice work

[Lehsyrus]

Fantastic job man, truly fantastic.

[dreamy23]

Great job!! but but what if they patch the hsf hacks

[Koios]

This would be a handy tool D:
Now ppl gonna be even lazier >.<

@Sid @Hell_Demon

Correction there is a distinct difference between easier and lazier this tool makes the tedious task more simple thus easier cutting time down, Lazy is the want not to do at all

[Dextroverse]

I'm having a problem with this part.

:: IMPORTANT! Edit this to where the game is!
:: %HOMEDRIVE% = Where windows is installed (eg. C:\)
set Directory=%HOMEDRIVE%\Nexon\Vindictus\en-US\

My directory for Vindictus is H:\Vindictus\en-US, and it seems to not be letting me successfully use the batch file - what is the proper way to enter it?

My C: Drive contains windows, but it's an SSD and it's full. Any chance to install it on a drive without windows on it?

[DanK]

I'm having a problem with this part.

:: IMPORTANT! Edit this to where the game is!
:: %HOMEDRIVE% = Where windows is installed (eg. C:\)
set Directory=%HOMEDRIVE%\Nexon\Vindictus\en-US\

My directory for Vindictus is H:\Vindictus\en-US, and it seems to not be letting me successfully use the batch file - what is the proper way to enter it?

My C: Drive contains windows, but it's an SSD and it's full. Any chance to install it on a drive without windows on it?

set Directory=H:\Vindictus\en-US\

Did you try that?

[Pie]

Correction there is a distinct difference between easier and lazier this tool makes the tedious task more simple thus easier cutting time down, Lazy is the want not to do at all

Yes. Making things easier, means people become susceptible to laziness.

[Dextroverse]

I have found the solution. There is a typo in the original posters installation instructions.

For this step, EnablerCheats folder should be like this C:\Nexon\Vindictus\en-US\EnableCheats
change this to EnablerCheats folder should be like this C:\Nexon\Vindictus\en-US\CheatFiles

Make sure to extract the Bot, Cheats, Mod, Backup folders directly inside the CheatFiles folder.
The rest of the instructions are correct. Hope this helps someone else having this problem.

[Kiette]

Great job!! but but what if they patch the hsf hacks

It checks to see if there is a change from the first time you ran it. Plus this is dependent on the hfs hacks to keep working, not the other way round. But yea, if those hfs hacks ever get blocked some how, then

I have found the solution. There is a typo in the original posters installation instructions.

For this step, EnablerCheats folder should be like this C:\Nexon\Vindictus\en-US\EnableCheats
change this to EnablerCheats folder should be like this C:\Nexon\Vindictus\en-US\CheatFiles

Make sure to extract the Bot, Cheats, Mod, Backup folders directly inside the CheatFiles folder.
The rest of the instructions are correct. Hope this helps someone else having this problem.

Yea sorry about that. I accidentally uploaded the wrong version of the batch file. The batch file in the code is the one it should be/look like. Try copying and pasting that. Even though its the wrong version, it will still work.

Correction there is a distinct difference between easier and lazier this tool makes the tedious task more simple thus easier cutting time down, Lazy is the want not to do at all

I'll be honest in that I'm really lazy. I see something idiotically tedious, I write a tool for it. I'd of done this in C++, but I started with a batch file and ended it with one. Plus it was a neat challenge to see if I could even do it. Surprisingly you can do a TON of things with batch files...


Can I get someone to approve the downloads again? I had to upload correct version. Sorry bout that