MpPassiveFishingBot v2.2 : PTS/LIVE fishing bot. Auto-updating pointer.

[mpmoi]

Hey guys !

This is a fishing bot for Trove ! It works well and is really useful if you want to fish a lot ! It supports multiple accounts ! It's purpose is to be a light and fast bot ! No hotkeys ! No setup needed !
Requierments : AutoHotKey (last version I guess)

How it works :
Just grab the source code and paste it in a .ahk file and start it! You can also download it directly. (wait for @Psychotic @Wyo @Buddie approval)
Start it (Tutorial here : https://www.mpgh.net/forum/showthread.php?t=1150041)
You can check PTS if you want to fish on it.
Press F on some water/lava/chocolate !
You can start it on as many accounts as you need !
If you want it to stop fishing just early reel the fishing rod ! (before a fish comes)
To close the bot simply close the tray icon or the GUI !

Updating pointers
This version should self-update pointers, however I will have to find them before so it could take some time (less than 2-3h after a patch usually)
You can still find them by yourself or check the forums : I guess Nippy's Fishbot pointers should work. Edit the config file in the same directory as the .ahk file. Then restart the script.
Here is a tutorial for finding pointers : https://www.mpgh.net/forum/showthread.php?t=1150085

/!\ People seems to have hurdles on non-english versions
/!\ Your fishing hotkey must be 'F'

 

#SingleInstance force
#Persistent

SplashTextOn, 500,25, mpPassiveFishingBot, Initializing and updating pointers, please wait...

SetWorkingDir %A_ScriptDir%
Reeled := Object()
Queue := Object()

global Ver:=2.2
global _Motd:=""
global _Version:=1
global _PTSVersion:=1
global _Pointer:="0x0"
global _PTSPointer:="0x0"
global _wOffset:="0x0"
global _lOffset:="0x0"
global _cOffset:="0x0"
global _PTSwOffset:="0x0"
global _PTSlOffset:="0x0"
global _PTScOffset:="0x0"
global iniFile := A_ScriptDir . "/config.ini"
global rld := 0

If (FileExist(iniFile)){
	IniRead, _Version, %iniFile%, Global, _Version
	IniRead, _Pointer, %iniFile%, Global, _Pointer
	IniRead, _wOffset, %iniFile%, Global, _wOffset
	IniRead, _lOffset, %iniFile%, Global, _lOffset
	IniRead, _cOffset, %iniFile%, Global, _cOffset
	IniRead, _PTSVersion, %iniFile%, Global, _PTSVersion
	IniRead, _PTSPointer, %iniFile%, Global, _PTSPointer
	IniRead, _PTSwOffset, %iniFile%, Global, _PTSwOffset
	IniRead, _PTSlOffset, %iniFile%, Global, _PTSlOffset
	IniRead, _PTScOffset, %iniFile%, Global, _PTScOffset
	IniRead, _Motd, %iniFile%, Global, _Motd
}

url := "https://dl.dropb" + "oxuserconten*****m/u/52517919/MpFishingBotPointer.txt"
WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WebRequest.Open("GET", url)
WebRequest.Send()

Contents := StrSplit(WebRequest.ResponseText, "$")

if (Contents[1] > _Version){
	global _Version:=Contents[1]
	global _Pointer:=Contents[2]
	global _wOffset:=Contents[3]
	global _lOffset:=Contents[4]
	global _cOffset:=Contents[5]
	IniWrite, %_wOffset%, %iniFile%, Global, _wOffset
	IniWrite, %_lOffset%, %iniFile%, Global, _lOffset
	IniWrite, %_cOffset%, %iniFile%, Global, _cOffset
	IniWrite, %_Version%, %iniFile%, Global, _Version
	IniWrite, %_Pointer%, %iniFile%, Global, _Pointer
	TrayTip ,mpPassiveFishingBot, % "Values updated to :`nPointer : " _Pointer "`nWater offset : " _wOffset "`nLava offset : "_lOffset "`nChocolate offset : " _cOffset
	Sleep, 10
	}

if (Contents[9] > _PTSVersion){
	global _PTSVersion:=Contents[9]
	global _PTSPointer:=Contents[10]
	global _PTSwOffset:=Contents[11]
	global _PTSlOffset:=Contents[12]
	global _PTScOffset:=Contents[13]
	IniWrite, %_PTSVersion%, %iniFile%, Global, _PTSVersion
	IniWrite, %_PTSPointer%, %iniFile%, Global, _PTSPointer
	IniWrite, %_PTSwOffset%, %iniFile%, Global, _PTSwOffset
	IniWrite, %_PTSlOffset%, %iniFile%, Global, _PTSlOffset
	IniWrite, %_PTScOffset%, %iniFile%, Global, _PTScOffset
	TrayTip ,mpPassiveFishingBot, % "PTS Values updated to :`nPointer : " _PTSPointer "`nWater offset : " _PTSwOffset "`nLava offset : "_PTSlOffset "`nChocolate offset : " _PTScOffset
	Sleep, 10
	}

global _newMotd:=Contents[8]
if (_Motd != _newMotd){
	TrayTip ,mpPassiveFishingBot, %_newMotd%
	Sleep, 10
	}
IniWrite, %_newMotd%, %iniFile%, Global, _Motd

Gui, 1:New
Gui 1:-Resize -MinimizeBox
Gui, 1:Add, Text,, Current version : %Ver%`n`nPointer : %_Pointer%`nWater offsets : %_wOffset%`nLava offset : %_lOffset%`nChocolate offset : %_cOffset%`n`nPTS Pointer : %_PTSPointer%`nPTS Water offsets : %_PTSwOffset%`nPTS Lava offset : %_PTSlOffset%`nPTS Chocolate offset : %_PTScOffset%
Gui, 1:Add, Text, vAccounts w200
Gui, 1:Add, Text, vReeled w200
Gui, 1:Add, Checkbox, vTry, PTS
Gui, 1:Add, Button, gDebug , &Debug

Gui, 2:New
Gui 2:-Resize -MinimizeBox
Gui, 2:Add, ListView, w700, Window PID|Handle|Base Address|Water Adress|Water Value|Lava Adress|Lava Value|Chocolate Adress|Chocolate Value

SplashTextOff

if (Contents[6] > Ver){
	num := Contents[7]
	url = https://www.mpgh.net/forum/showthread.php?t=%num%
	MsgBox, 4,, New version available, go to MPGH topic ? (press Yes or No)
	IfMsgBox Yes
		Run %url%
	}

Gui, 1:Show,,mpPassiveFishingBot

SetTimer, Scan, 999
SetTimer, Relaunch, 1999
SetTimer, UpdateGui, 250

TrayTip ,mpPassiveFishingBot, Bot started ! Press "f" on water/lava/chocolate !
return

Scan:
	WinGet, l, list, ahk_exe Trove.exe
	Loop %l%
	{
		Handle := l%a_index%
		WinGet, pid, PID, ahk_id %Handle%
		Base := getProcessBaseAddress(Handle)
		If PTS = 1
		{
			wAddress := GetAddress(pid, Base, _PTSPointer, _PTSwOffset)
			lAddress := GetAddress(pid, Base, _PTSPointer, _PTSlOffset)
			cAddress := GetAddress(pid, Base, _PTSPointer, _PTScOffset)
		}Else{
			wAddress := GetAddress(pid, Base, _Pointer, _wOffset)
			lAddress := GetAddress(pid, Base, _Pointer, _lOffset)
			cAddress := GetAddress(pid, Base, _Pointer, _cOffset)
		}
		wValue := ReadMemory(wAddress, pid)
		lValue := ReadMemory(lAddress, pid)
		cValue := ReadMemory(cAddress, pid)
		if (cValue=1||lValue=1||wValue=1){
			found := 0
			for i, p in Reeled{
				if (p=pid)
					found := 1
				}
			for i, p in Queue{
				if (p=pid)
					found := 1
				}
			If (found = 0){
				ControlSend, , {f down}, ahk_pid %pid%
				Sleep, 90
				ControlSend, , {f up}, ahk_pid %pid%
				rld ++
				Reeled.Insert(pid)
				}
			}
	}
	return

Relaunch:
	Queue := Reeled
	Reeled := Object()
	Sleep, 2000
	for i, p in Queue{
		ControlSend, , {f down}, ahk_pid %p%
		Sleep, 90
		ControlSend, , {f up}, ahk_pid %p%
		}
	return

UpdateGui:
	C := 0
	WinGet, l, list, ahk_exe Trove.exe
	Loop %l%
		C ++
	GuiControl, 1:, Accounts, Active accounts : %C%
	GuiControl, 1:, Reeled, Fish reeled : %rld%
	GuiControlGet, PTS,, Try
	return

GuiClose:
	ExitApp

Debug:
	SetTimer, UpdateDebugGui, 250
	Gui, 2:Show, , mpPassiveFishingBotDebug
	return

UpdateDebugGui:
	Gui, 2:Default
	LV_DELETE()
	WinGet, l, list, ahk_exe Trove.exe
	Loop %l%
	{
		Handle := l%a_index%
		WinGet, pid, PID, ahk_id %Handle%
		BaseAddress := getProcessBaseAddress(Handle)
		If PTS = 1
		{
			wAddress := GetAddress(pid, BaseAddress, _PTSPointer, _PTSwOffset)
			lAddress := GetAddress(pid, BaseAddress, _PTSPointer, _PTSlOffset)
			cAddress := GetAddress(pid, BaseAddress, _PTSPointer, _PTScOffset)
		}Else{
			wAddress := GetAddress(pid, BaseAddress, _Pointer, _wOffset)
			lAddress := GetAddress(pid, BaseAddress, _Pointer, _lOffset)
			cAddress := GetAddress(pid, BaseAddress, _Pointer, _cOffset)
		}
		wValue := ReadMemory(wAddress, pid)
		lValue := ReadMemory(lAddress, pid)
		cValue := ReadMemory(cAddress, pid)
		BaseAddressHex := Hex(BaseAddress)
		wAddressHex := Hex(wAddress)
		lAddressHex := Hex(lAddress)
		cAddressHex := Hex(cAddress)
		LV_Add("", Handle, PID, BaseAddressHex, wAddressHex, wValue, lAddressHex, lValue, cAddressHex, cValue)
	}
	return

2GuiClose:
	SetTimer, UpdateDebugGui, Off
	Gui, 2:Hide
	return

Hex(n){
	VarSetCapacity(S,66,0)
	DllCall("msvcrt\_i64tow", "Int64",n, "Str",S, "UInt",16, "CDECL")
	Return S
	}

getProcessBaseAddress(Handle){
	Return DllCall( A_PtrSize = 4 ? "GetWindowLong": "GetWindowLongPtr", "Ptr", Handle, "Int", -6, "Int64")
	}

GetAddress(PID, Base, Address, Offset){
	p := ReadMemory(base + Address,PID)	
	OffsetSplit := StrSplit(Offset, "+")
	OffsetCount := OffsetSplit.MaxIndex()
	Loop, %OffsetCount%{
		If (a_index = OffsetCount)
			p := p + OffsetSplit[a_index]
	  	Else
			p := ReadMemory(p + OffsetSplit[a_index],PID)
		}
	Return p
	}

ReadMemory(MADDRESS, pid){
	VarSetCapacity(MVALUE,4,0)
	ProcessHandle := DllCall("OpenProcess", "Int", 24, "Char", 0, "UInt", pid, "UInt")
	DllCall("ReadProcessMemory", "UInt", ProcessHandle, "Ptr", MADDRESS, "Ptr", &MVALUE, "Uint",4)
	Loop 4
			result += *(&MVALUE + A_Index-1) << 8*(A_Index-1)
	Return result
	}

 

 

V1.0 (2670b):
Initial release

v1.1 (2781b):
Timer correction
Hard optimisation

v1.2 (3659b):
Now automatically updating pointers !
Few issues corrected

v1.3 (3649b):
Splash text
Tray messages added (no longer messages box)
Few optimisations

v1.4 (3830b):
Edited timer setup
Less hurdles with bot stuck (reeling while fishing)

v1.5 (4231b):
Check for updates and open related thread
MOTD added (for changelogs)
Edited timer setup
Less hurdles with bot stuck (reeling while fishing)

v1.6 (4697b):
GUI Added
Removed useless stuff
Now counting found accounts and reeled fish

v1.7 (6237b):
Debug added

v1.8 (6267b):
Corrected a cross-GUI fix

v1.9 (6266b):
Fixed a closing bug

v2.0 (8116b):
Fixed a glitch on the base address on debug window
Added a PTS support

v2.1 (7990b):
Modified window selection to prevent selection non-trove window
Removed handle reading (already have it)
Cleaned up initial values of pointer/offsets(were wrong)

2.2 (7529b):
Minor optimisations and crash fixes

Special thanks :
@reppin Who let me make a bot and use part of it's memory-reading code ! Check out his awesome fishing bot !

Disclaimer :
I will not add any bootdrop/destroy and loot-collect thing any soon ! This is a bot made for 5-min botting session when you go eating or to the toilets mid-game.
I will not be responsible of any ban you get by using this !

There are the virus scans :
https://virusscan.jotti.org/en-US/fi...job/odud7149jw
https://www.virustotal.com/en/file/e...is/1478709448/

NOTE : Old thread can be closed

[Hunter]

Just a harmless game script.

/Approved. Post back results and as always, use at your own.

[loghorizon]

What is the difference with version 2.1?

[Faelene]

Pointer doesn't work for Nippy's

[mpmoi]

What is the difference with version 2.1?

Mainly memory reading stuff, I had it for a while so I posted it.

- - - Updated - - -

Pointer doesn't work for Nippy's

I'll take a look tonight

- - - Updated - - -

Pointer updated to : 0x00C8FF24

- - - Updated - - -

Confirmed working on all liquids on this bot

[juan jaho]

It is working, but when i have two account running and stopped fishing on one of them, both will stop auto fishing. thx.
p.s. are the chances of getting ban high using this program?

[mpmoi]

It is working, but when i have two account running and stopped fishing on one of them, both will stop auto fishing. thx.
p.s. are the chances of getting ban high using this program?

Gotta check this out. And chances scales with the amount of time and account you use

[mpmoi]

Hey ! Fixed almost everything about the multi account crash ! I'll post an update in few hours ! (Gotta test a few before )
Also I'll be removing PTS support as I can't keep it updated.
Finally I'll have to add a hotkey to start the bot so itll be more stable.

[mpmoi]

Not working yet, gotta fix some more crashes