MpPassiveFishingBot v3.0 : Multi-account Fishbot

[mpmoi]

Hey guys !

Big update on the fishing bot, fixed everything about the multiple account glitches

Requierments : AutoHotKey (last version I guess)

How it works :
Just grab the source code and paste it in a .ahk file and start it! You can also download it directly. (wait for @Psychotic @Wyo @Buddie approval)
Start it (Tutorial here : https://www.mpgh.net/forum/showthread.php?t=1150041 (maybe outdated))
Press ctrl + F on some water/lava/chocolate !
You can start it on as many accounts as you need !
If you want it to stop fishing just press ctrl + F again !
To close the bot simply close the the GUI !

Updating pointers :
This version should self-update pointers, however I will have to find them before so it could take some time (less than 2-3h after a patch usually)
You can still find them by yourself or check the forums : I guess Nippy's Fishbot pointers should work. Edit the config file in the same directory as the .ahk file. Then restart the script.
Here is a tutorial for finding pointers : https://www.mpgh.net/forum/showthread.php?t=1150085

Not working ?
-After an update :
Check the last comments to see if there's any new pointer.
If not, post here and wait for someone to post it or me to update it
-Script not starting :
Describe your issue here in comment
-Other :
Press the 'info' button on the GUI, then press "Copy Debug Data" and paste it here. It should look like this :

 

Version = 3.0
Pointer = 0x00C8FF24
Water Offsets = 0x8+0xb4+0x28+0x22c
Lava Offsets = 0x8+0xb4+0x28+0x6e8
Chocolate Offsets = 0x8+0xb4+0x28+0x488
Water State Offsets = 0x1bc+0x4+0x748+0x1ec
Lava State Offsets = 0x1bc+0x4+0x690+0x88
Chocolate State Offsets = 0x1bc+0x4+0x748+0x448
Client:
PID = 4336
Handle = 0x200570
Base = 17104896
Water Address = 96185852
Lava Address = 96187064
Chocolate Address = 96186456
Water State Address = 96183132
Lava State Address = 96182528
Chocolate State Address = 96183736
Client:
PID = 8840
Handle = 0x560580
Base = 17104896
Water Address = 90353164
Lava Address = 90354376
Chocolate Address = 90353768
Water State Address = 90350444
Lava State Address = 90349840
Chocolate State Address = 90351048

Then wait for an answer

/!\ People seems to have hurdles on non-english versions
/!\ Your fishing hotkey must be 'F'

 

#SingleInstance force
#Persistent

SetBatchLines -1

SplashTextOn, 500,25, mpPassiveFishingBot, Initializing and updating pointers, please wait...

SetWorkingDir %A_ScriptDir%
Active := Object()

global Ver:=3.0
global _Version:=1
global _Pointer:="0x0"
global _PTSPointer:="0x0"
global _wOffset:="0x0"
global _lOffset:="0x0"
global _cOffset:="0x0"
global _wStateOffset:="0x0"
global _lStateOffset:="0x0"
global _cStateOffset:="0x0"
global iniFile := A_ScriptDir . "/config.ini"

If (FileExist(iniFile)){
	IniRead, _Version, %iniFile%, Global, _Version
	IniRead, _Pointer, %iniFile%, Global, _Pointer
	IniRead, _wOffset, %iniFile%, Global, _wOffset
	IniRead, _lOffset, %iniFile%, Global, _lOffset
	IniRead, _cOffset, %iniFile%, Global, _cOffset
	IniRead, _wStateOffset, %iniFile%, Global, _wStateOffset
	IniRead, _lStateOffset, %iniFile%, Global, _lStateOffset
	IniRead, _cStateOffset, %iniFile%, Global, _cStateOffset
}

url := "https://dl.dropb" + "oxuserconten*****m/u/52517919/MpFishingPointer.txt"
WebRequest := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WebRequest.Open("GET", url)
WebRequest.Send()

Contents := StrSplit(WebRequest.ResponseText, "$")

if (Contents[1] > _Version){
	global _Version:=Contents[1]
	global _Pointer:=Contents[2]
	global _wOffset:=Contents[3]
	global _lOffset:=Contents[4]
	global _cOffset:=Contents[5]
	global _wStateOffset:=Contents[6]
	global _lStateOffset:=Contents[7]
	global _cStateOffset:=Contents[8]
	IniWrite, %_wOffset%, %iniFile%, Global, _wOffset
	IniWrite, %_lOffset%, %iniFile%, Global, _lOffset
	IniWrite, %_cOffset%, %iniFile%, Global, _cOffset
	IniWrite, %_wStateOffset%, %iniFile%, Global, _wStateOffset
	IniWrite, %_lStateOffset%, %iniFile%, Global, _lStateOffset
	IniWrite, %_cStateOffset%, %iniFile%, Global, _cStateOffset
	IniWrite, %_Version%, %iniFile%, Global, _Version
	IniWrite, %_Pointer%, %iniFile%, Global, _Pointer
	TrayTip ,mpPassiveFishingBot, % "Values updated to :`nPointer : " _Pointer "`nWater offset : " _wOffset "`nLava offset : "_lOffset "`nChocolate offset : " _cOffset "`nWater state offset : " _wStateOffset "`nLava state offset : "_lStateOffset "`nChocolate state offset : " _cStateOffset
	}

Gui, 1:New
Gui 1:-Resize -MinimizeBox
Gui, 1:Add, ListView, Checked -Hdr grid -ReadOnly -LV0x10 w1100, | | | | | | | | | | | | | | | | |
Gui, 1:Add, Button, gInfo w1100, &Info

Gui, 2:New
Gui 2:-Resize -MinimizeBox
Gui, 2:Add, Text,, Current version : %Ver%`n`nPointer : %_Pointer%`nWater offsets : %_wOffset%`nLava offset : %_lOffset%`nChocolate offset : %_cOffset%`nWater state offsets : %_wStateOffset%`nLava state offset : %_lStateOffset%`nChocolate state offset : %_cStateOffset%
Gui, 2:Add, Button, gDebug , &Copy Debug Data

SplashTextOff

if (Contents[9] > Ver){
	num := Contents[10]
	url = https://www.mpgh.net/forum/showthread.php?t=%num%
	MsgBox, 4,, New version available, go to MPGH topic ? (press Yes or No)
	IfMsgBox Yes
		Run %url%
	}

GUI, 1:Show, ,mpPassiveFishingBot

SetTimer, Scan, 999
SetTimer, UpdateGui, 999

TrayTip ,mpPassiveFishingBot, Bot started ! Press "f" on water/lava/chocolate !
return

#IfWinActive, Trove
^f::
	WinGet, p, pid, A
	WinGet, pName, ProcessName, ahk_pid %p%
	if(pName = "Trove.exe"){
		New := Object()
		found := false
		for i, C in Active{
			if (C[1] = p)
				found := true
			else
				New.Insert(C)
		}
		if (!found){
			NC := [p,0,9]
			New.Insert(NC)
			TrayTip ,mpPassiveFishingBot, Bot started on %p%!
		}else{
			TrayTip ,mpPassiveFishingBot, Bot stopped on %p%!
		}
		Active := New
	}
	return

Scan:
	for i, C in Active{
		C[3] ++
		if (C[3]>5){
			pid := C[1]
			WinGet, Handle, ID, ahk_pid %pid%
			Base := getProcessBaseAddress(Handle)
			wAddress := GetAddress(pid, Base, _Pointer, _wOffset)
			lAddress := GetAddress(pid, Base, _Pointer, _lOffset)
			cAddress := GetAddress(pid, Base, _Pointer, _cOffset)
			wValue := ReadMemory(wAddress, pid)
			lValue := ReadMemory(lAddress, pid)
			cValue := ReadMemory(cAddress, pid)
			if (cValue=1||lValue=1||wValue=1){
				C[2] ++
				C[3] := 3
				ControlSend, , f, ahk_pid %pid%
			}else{
				wStateAddress := GetAddress(pid, Base, _Pointer, _wStateOffset)
				lStateAddress := GetAddress(pid, Base, _Pointer, _lStateOffset)
				cStateAddress := GetAddress(pid, Base, _Pointer, _cStateOffset)
				wStateValue := ReadMemory(wStateAddress, pid)
				lStateValue := ReadMemory(lStateAddress, pid)
				cStateValue := ReadMemory(cStateAddress, pid)
				if (cStateValue = 0 && lStateValue = 0 && wStateValue = 0){
					C[3] := 0
					ControlSend, , f, ahk_pid %pid%
				}
			}
		}
	}
	return

Info:
	Gui, 2:Show, , Info
	return

Debug:
	message := "[SP" . "OILER=Debug][CO" . "DE]Version = " . Ver . "`nPointer = " . _Pointer . "`nWater Offsets = " . _wOffset . "`nLava Offsets = " . _lOffset . "`nChocolate Offsets = " . _cOffset . "`nWater State Offsets = " . _wStateOffset . "`nLava State Offsets = " . _lStateOffset . "`nChocolate State Offsets = " . _cStateOffset
	WinGet, l, list, ahk_exe Trove.exe
	Loop %l%
	{
		Handle := l%a_index%
		WinGet, pid, PID, ahk_id %Handle%
		Base := getProcessBaseAddress(Handle)
		wAddress := GetAddress(pid, Base, _Pointer, _wOffset)
		lAddress := GetAddress(pid, Base, _Pointer, _lOffset)
		cAddress := GetAddress(pid, Base, _Pointer, _cOffset)
		wStateAddress := GetAddress(pid, Base, _Pointer, _wStateOffset)
		lStateAddress := GetAddress(pid, Base, _Pointer, _lStateOffset)
		cStateAddress := GetAddress(pid, Base, _Pointer, _cStateOffset)
		message := message . "`nClient" . i . ":`nPID = " . pid . "`nHandle = " . Handle . "`nBase = " . Base . "`nWater Address = " . wAddress . "`nLava Address = " . lAddress . "`nChocolate Address = " . cAddress . "`nWater State Address = " . wStateAddress . "`nLava State Address = " . lStateAddress . "`nChocolate State Address = " . cStateAddress
		}
	message := message . "[/CO" . "DE][/SPO" . "ILER]"
	clipboard = %message%
	MsgBox, Debug data copied to clipboard
	return

GuiClose:
	ExitApp

UpdateGui:
	LV_DELETE()
	LV_Add("", "Window PID","Handle","Base Address","Water Adress","V","Lava Adress","V","Chocolate Adress","V","Water State Adress","V","Lava State Adress","V","Chocolate State Adress","V", "Reeled", "Timer")
	WinGet, l, list, ahk_exe Trove.exe
	Loop %l%
	{
		Handle := l%a_index%
		WinGet, pid, PID, ahk_id %Handle%
		Base := getProcessBaseAddress(Handle)
		wAddress := GetAddress(pid, Base, _Pointer, _wOffset)
		lAddress := GetAddress(pid, Base, _Pointer, _lOffset)
		cAddress := GetAddress(pid, Base, _Pointer, _cOffset)
		wValue := ReadMemory(wAddress, pid)
		lValue := ReadMemory(lAddress, pid)
		cValue := ReadMemory(cAddress, pid)
		wStateAddress := GetAddress(pid, Base, _Pointer, _wStateOffset)
		lStateAddress := GetAddress(pid, Base, _Pointer, _lStateOffset)
		cStateAddress := GetAddress(pid, Base, _Pointer, _cStateOffset)
		wStateValue := ReadMemory(wStateAddress, pid)
		lStateValue := ReadMemory(lStateAddress, pid)
		cStateValue := ReadMemory(cStateAddress, pid)
		found := false
		for i, C in Active{
			p := C[1]
			if (p = pid){
				found := true
				LV_Add("Check", PID, Handle, Base, wAddress, wValue, lAddress, lValue, cAddress, cValue, wStateAddress, wStateValue, lStateAddress, lStateValue, cStateAddress, cStateValue, C[2], C[3])
			}
		}
		if (!found)
			LV_Add("", PID, Handle, Base, wAddress, wValue, lAddress, lValue, cAddress, cValue, wStateAddress, wStateValue, lStateAddress, lStateValue, cStateAddress, cStateValue,0,0)
	}
	LV_ModifyCol()
	return

getProcessBaseAddress(Handle){
	Return DllCall( A_PtrSize = 4 ? "GetWindowLong": "GetWindowLongPtr", "Ptr", Handle, "Int", -6, "Int64")
	}

GetAddress(PID, Base, Address, Offset){
	p := ReadMemory(base + Address,PID)	
	OffsetSplit := StrSplit(Offset, "+")
	OffsetCount := OffsetSplit.MaxIndex()
	Loop, %OffsetCount%{
		If (a_index = OffsetCount)
			p := p + OffsetSplit[a_index]
	  	Else
			p := ReadMemory(p + OffsetSplit[a_index],PID)
		}
	Return p
	}

ReadMemory(MADDRESS, pid){
	VarSetCapacity(MVALUE,4,0)
	ProcessHandle := DllCall("OpenProcess", "Int", 24, "Char", 0, "UInt", pid, "UInt")
	DllCall("ReadProcessMemory", "UInt", ProcessHandle, "Ptr", MADDRESS, "Ptr", &MVALUE, "Uint",4)
	Loop 4
			result += *(&MVALUE + A_Index-1) << 8*(A_Index-1)
	Return result
	}

 

 

V1.0 (2670b):
Initial release

v1.1 (2781b):
Timer correction
Hard optimisation

v1.2 (3659b):
Now automatically updating pointers !
Few issues corrected

v1.3 (3649b):
Splash text
Tray messages added (no longer messages box)
Few optimisations

v1.4 (3830b):
Edited timer setup
Less hurdles with bot stuck (reeling while fishing)

v1.5 (4231b):
Check for updates and open related thread
MOTD added (for changelogs)
Edited timer setup
Less hurdles with bot stuck (reeling while fishing)

v1.6 (4697b):
GUI Added
Removed useless stuff
Now counting found accounts and reeled fish

v1.7 (6237b):
Debug added

v1.8 (6267b):
Corrected a cross-GUI fix

v1.9 (6266b):
Fixed a closing bug

v2.0 (8116b):
Fixed a glitch on the base address on debug window
Added a PTS support

v2.1 (7990b):
Modified window selection to prevent selection non-trove window
Removed handle reading (already have it)
Cleaned up initial values of pointer/offsets(were wrong)

v2.2 (7529b):
Minor optimisations and crash fixes

v3.0 (8431b):
Core code remade
Fixed crash with multiple accounts
GUI looks better
Added a button to copy account and vars list, BBCODE formatted

Special thanks :
@reppin Who let me make a bot and use part of it's memory-reading code ! Check out his awesome fishing bot !

Disclaimer :
I will not be responsible of any ban you get by using this !

There are the virus scans :
https://www.virustotal.com/en/file/5...is/1479313668/
https://virusscan.jotti.org/en-US/fi...job/z23lirqpjf

NOTE : Old thread can be closed

[Bryan]

Good job , /Approved

[mpmoi]

Thanks @Buddie ! Feel free to close this thread, so ppl won't be bumping it ! https://www.mpgh.net/forum/showthread.php?t=1189613

[Repetitionman]

hmm, sorry, but it reels in much too fast... :
(

[mpmoi]

What do you mean ?

[meocondilac]

It reels in even without fish

[mpmoi]

Is the water value at 1 when it reels ?

[meocondilac]

i don't think so everything was at 0 and the timer was somewhere around 5...ver 2.2 works w/o any prob

[mpmoi]

i don't think so everything was at 0 and the timer was somewhere around 5...ver 2.2 works w/o any prob

Are you having lags? Have you changed the update time ?

- - - Updated - - -

Try changing this line :

if (C[3]>5)

by

if (C[3] > 10)

Also send me the debug thing please

[meocondilac]

I don't have any lag atm and no just download==>open==>try it out==>reels w/o fish. What did i do wrong?

[mpmoi]

I don't really know..
Try this :

-Other :
Press the 'info' button on the GUI, then press "Copy Debug Data" and paste it here.

- - - Updated - - -

Or maybe this :

Try changing this line :
Code:
if (C[3]>5)
by
Code:
if (C[3] > 10)

- - - Updated - - -

Also, when you fish in water(without the bot activated), is the value after Water state address to 1 for this account ?

[meocondilac]

Or maybe this :
Originally Posted by mpmoi
Try changing this line :
Code:
if (C[3]>5)
by
Code:
if (C > 10)

This? Scan:
for i, C in Active{
C[3] ++
if (C > 10)
And the debug thinggy:

 

Version = 3.0
Pointer = 0x00C8FF24
Water Offsets = 0x8+0xb4+0x28+0x22c
Lava Offsets = 0x8+0xb4+0x28+0x6e8
Chocolate Offsets = 0x8+0xb4+0x28+0x488
Water State Offsets = ERROR
Lava State Offsets = ERROR
Chocolate State Offsets = ERROR
Client1:
PID = 206424
Handle = 0x3059e
Base = 3735552
Water Address = 63741772
Lava Address = 63742984
Chocolate Address = 63742376
Water State Address = 
Lava State Address = 
Chocolate State Address =

Also, when you fish in water(without the bot activated), is the value after Water state address to 1 for this account ?

ummm no?

[mpmoi]

Missspelled, sorry,
this :

for i, C in Active{
C[3] ++
if (C (3] > 10)

- - - Updated - - -

Found the error, hold on !

- - - Updated - - -

Try deleting the config.ini file and restarting the bot. If this doesn't work try editing the config.ini file and put this in :

[Global]
_wOffset=0x8+0xb4+0x28+0x22c
_lOffset=0x8+0xb4+0x28+0x6e8
_cOffset=0x8+0xb4+0x28+0x488
_wStateOffset=0x1bc+0x4+0x748+0x1ec
_lStateOffset=0x1bc+0x4+0x690+0x88
_cStateOffset=0x1bc+0x4+0x748+0x448
_Version=42
_Pointer=0x00C8FF24

- - - Updated - - -

hmm, sorry, but it reels in much too fast... :
(

It's likely you have the same problem as @meocondilac
You should try removing the config.ini file and restart the script !
The config.ini file requiered is not the same !

- - - Updated - - -

Forced a pointer update on the client, everything should go back to normal guys
Thanks for helping @meocondilac <3

- - - Updated - - -

Editing the config.ini file is no longer needed ! However I'd recommend deleting it before starting the bot for the first tme if you put this in the same directory as previous versions !

[meocondilac]

Try deleting the config.ini file and restarting the bot. If this doesn't work try editing the config.ini file and put this in :
Code:
[Global]
_wOffset=0x8+0xb4+0x28+0x22c
_lOffset=0x8+0xb4+0x28+0x6e8
_cOffset=0x8+0xb4+0x28+0x488
_wStateOffset=0x1bc+0x4+0x748+0x1ec
_lStateOffset=0x1bc+0x4+0x690+0x88
_cStateOffset=0x1bc+0x4+0x748+0x448
_Version=42
_Pointer=0x00C8FF24

water value is 1 but my char just standing there doing notthing(not reeling anything or throwing the line) XD
My bad everything seem to be working now thanks mpmoi for your fast response and trying to fix things right <3

[mpmoi]

water value is 1 but my char just standing there doing notthing(not reeling anything or throwing the line) XD

Start with a fresh .ahk file (without changes)
And if :
-Water state value is 1 : You have a lure in water
-Water value is 1 : You have a fish on the lure

- - - Updated - - -

Send again the debug thing so I can check if address look correct